印刷時のタイムスタンプ機能 - 秀丸エディタ関連ソフト会議室 - スレッド03389, 1999/05/26

印刷時のタイムスタンプ機能

海苔さん　99/05/26 10:30

海苔と申します。

秀丸エディタには毎日ひじょうにお世話になっております。

さて、掲題の件についてですが、現在、ファイルを印刷して手で校正して、また打ち
出すという作業をしています。
ファイル名とページ数は印刷するときに出るのですが、バージョンを記入しておかな
いと、順番がくちゃくちゃになってしまいがちですのでタイムスタンプを付けたいの
ですが、それはどのようにしたらよいでしょうか。その機能が現在デフォルトでつい
ていないようですので、もしマクロか何かで処理できるなら、その方法について教え
ていただければ幸いです。

よろしくご教示お願いします。

RE:03389 印刷時のタイムスタンプ機能

番頭++ さん　99/05/26 12:30

>ていないようですので、もしマクロか何かで処理できるなら、その方法について教え
>ていただければ幸いです。

//*1 こんな感じですか !!!

//*1 a1.mac
#x = x; #y = y;
gofiletop;
insert date + " - " + time + "\n\n";
print;
// undo; // 現在は print; の後の undo; はできないので、
gofiletop; deleteline; deleteline; // 自分で削除する ...
// moveto #x, #y;
moveto 00, #y;
endmacro;

//*1 a2.mac
#x = x; #y = y;
gofiletop;
insert filename2 + " - " + date + " - " + time + "\n\n";
print;
gofiletop; deleteline; deleteline;
moveto 00, #y;
// save; // 必要無いかも !!!
endmacro;

RE:03392 印刷時のタイムスタンプ機能

番頭++ さん　99/05/26 13:22

>//*1 こんな感じですか !!!

//*1 それとも、こんな感じですかな !!!

//*1 a3.mac
disabledraw; #x = x; #y = y; selectall; copy; moveto 00, #y;
#i = val(leftstr(date,2));
$date = midstr("19,20",(!(#i<80)-1)*3,2);
$date = $date + leftstr(date,2) + "." + midstr(date,3,2) + "." + midstr(date,6,2);
$wk1 = basename2 + " - " + $date + " - " + time;
openfile "/h "; changename $wk1; paste;
print; quit;
endmacro;

RE:03393 印刷時のタイムスタンプ機能

番頭++ さん　99/05/26 17:41

まともなマクロにしました。後は自力本願ということで ...

//*1 KZ_Print_DT1.mac
//*1 ファイル名に日付、時刻を付加して一時的に変更後、印刷します。
//*1 " basename2 - yyyy.mm.dd - hhm:mm " のようなファイル名となります。
//*1 当然、保存はしません、出来ません。

//*1 【注意】
// ・ファイル内容の転送は ClipBoard 経由で行っています。
// ・ファイルの容量が ClipBoard で処理できる容量を超えると、正常に処理できません。
// ・マクロの終了時に、 ClipBoard をクリアしています。

if( basename == "" ){ endmacro; } // 無題だとやめる !!!
escape; disabledraw;
$str_file1 = filename2;
#x = x; #y = y;
gofiletop;
insert filename2 + " - " + date + " - " + time + "\n\n"; // 必要かな 2 !!!
selectall; copy;
undo; // 必要かな 2 !!!
//R gofiletop; deleteline; deleteline; // 自分で削除する ...
moveto 00, #y; //R moveto #x, #y;
//R if( updated ){ save; } // 必要無いかも !!!
$wk1 = midstr("19,20",(!((val(leftstr(date,2)))<80)-1)*3,2);
$wk1 = $wk1 + leftstr(date,2) + "." + midstr(date,3,2) + "." + midstr(date,6,2);
$wk1 = basename2 + " - " + $wk1 + " - " + leftstr(time,5); // hh:mm - : <== invalid.
//R $wk1 = basename2 + " - " + $wk1 + " - " + leftstr; // hh:mm:ss
openfile "/h " + $wk1;
selectall; delete; paste;
//R CHANGENAME;
//R if( ! result ){ endmacro; }
print; // 事前に印刷 (オプション) 、プリンタの設定が必要です。
setactivehidemaru hidemaruhandle(findhidemaru($str_file1));
closehidemaruforced hidemaruhandle(findhidemaru($wk1));
setclipboard ""; // ClipBoard クリア
endmacro;

RE:03396 印刷時のタイムスタンプ機能

ENCODINGSHIFTJIS さん　99/09/20 17:46

>まともなマクロにしました。後は自力本願ということで ...
>

小型軽量の伝統芸能に反するかも知れないが、在る物に丸投げ
する手もあります。ブラウザーは表示が命ですからつつけば色々できます。
イージーかどうかは知らないが。書体変更、着色・・・・
日本語の通る軽量ブラウザーがあるといいのですが。
------------------------------------------------------------
jsprint.mac
$thisname = filename;// save済　ファイル名
openfile "c:\\windows\\temp\\pjs.html"; // js の部分書き換えに
changename "c:\\windows\\temp\\print.html";
replaceall "filename",$thisname; replaceall "\\","\\\\";
save;
// 1-file 分のquit; や saveexit; でマクロ終了？！　マルチファイル対応なのに
run "start c:\\windows\\temp\\print.html"; // 書き換えたjsを起動
quit;
-------------------------------------------------------------
c:\windows\temp\pjs.html　　マスターのhtml
<HTML>
<HEAD><TITLE>手近のスクリプトでデータ処理</TITLE></HEAD>

<BODY onLoad="print()"><OL><SCRIPT language="JavaScript">
var fobj, txtf, lstr; ForReading=1;
document.title="filename";// ファイル名をタイトルに
fobj = new ActiveXObject("Scripting.FileSystemObject");
//fldr=fobj.GetFolder(".");
//alert(fldr); // ?? よく分らない実装の違いが大きすぎる
txtf = fobj.OpenTextFile("filename",ForReading);
while(!txtf.AtEndOfStream){
lstr=txtf.ReadLine();
//alert(lstr);
document.write("<LI>" + lstr); // 1 行ずつ番号付き箇条書きに
}
</SCRIPT></OL></BODY>
</HTML>

RE:04043 印刷時のタイムスタンプ機能

番頭++ さん　99/09/20 18:08

ふむふむ ...
すごいアイデアですね、でも html のプリントに困りそうです。
< > とか、いくつかの特殊文字をエスケープ (&) しなくては、疲れる。
単純に <pre> </pre> を入れるだけで良いような気がします。

印刷のアプリに頼るのが一番でしょう。

RE:04044 印刷時のタイムスタンプ機能

ENCODINGSHIFTJIS さん　99/09/21 19:40

>ふむふむ ...

HTMLもJavaScriptも細かいところは話せば長い。これからも益々長くなる。
タグと混合の埋め込みプログラミングは綺麗じゃないがＰＳやＢＡＳＩＣ
よりは少しマシかな？。表の自動割り付けの例です。
　　　　　in text 表モデルはhtmlモデルとする
.table caption何とか
aaa,bbb,ccc
dddd,,eeee
./table
　　　　　html 表示印刷（<body の　onLoad= で　print() してます）
if(".table" == lstr.substr(0,".table".length)){
document.write("<TABLE><CAPTION>"+lstr.substr(6)+"</CAPTION>")
while("./table" != (lstr=txtf.ReadLine(),lstr.substr(0,7))){
items=lstr.split(",");// CSV を切り分ける
document.write("<TR>");
for(i=0;items.length>i;i++){
document.write("<TD>"+items[i]); }
}
document.write("</TABLE>");
}
else{// その他の行 //alert(lstr);
document.write(lstr.replace(/</g,"<")+"<BR>");} // タグつぶし付き
}
これを行ループに組み込む,以下同様・・・

RE:04051 印刷時のタイムスタンプ機能

番頭++ さん　99/09/21 20:19

>>ふむふむ ...

えーと、
ソフト、ハードと言う、クローズされたオブジェクトは会話をします。
それは一つの言語でコミュニケーションをとるのが好きです。
個人的な意見ですが、二人の通訳が必要な会話は望みません。好みです。
年で新しい物を敬遠する世代です、好き嫌いはありますでしょう ...