| |
皆さんさん、今日は、ひろです。hidesoft.8:01403 へのレスです。
kendo さん、まず hidesoft.2:08590 のスレッドで解決済みだと思いますが、maruo.
exe と hidemaru.exe は、メニューが英語か日本語化の違いだけなので、別けて使う必
要はありません。単に表示フォントを変更すれば済みます。
> １．まずアルファベットにtexのテキストみたくタグをつけるのです。
<中略>
> ２．例をフランス語で続けましょう。フランス語用の元辞書（francais.dic）を
> WebでＤＬしてきて、
<中略>
> この辞書はテキストファイルなのです。この文字を"c1"で一
> 括変換してしまいます。以下、他のものも同じです。
<中略>
> ３．buildhashという実行ファイルでispellで使用するバイナリーの辞書ファイ
> ルを作成します。ただし、buildhash.exeに作成上のオプションを与えるファイ
> ルにfrancais.affというのがありますが、これもテキストファイルで。maruoな
> どで開いて同じようにフランス語固有の文字を、さっきの"c1"のようにすべて置
> 換してしまいます。
<中略>
> ４．出来上がったバイナリのフランス語用辞書をひろさんのマクロで立ち上げる
> ようにします。もう辞書には一切フランス語固有の文字は含まれていませんから、
> 日本語にフランス語文字が入っていても問題ありません。
<中略>
> ５．チェックが済んだら、今度は「"franc2ais"などとあるのを秀丸の一括置換
> のマクロを作って、フランス語に戻せば......」ということ
<中略>
> ６．maruoなどでフランス語のみで日本語に混ぜずに書けば、それをひろさんの
> マクロを立ち上げてチェックして、さらにmaruo（英語版秀丸）で何かの一括置
> 換マクロと使って純正のフランス語表記に直せます。
なるほどこうすればある程度は、スペルチェックと英語以外の処理が出来
そうですね。
スペルチェックは何度もやるかもしれないので、置換部分だけマクロ化す
ればよいですね。単純にアルファベットと数字によって ASCII 文字以外の
西欧文字を表しているなら、次のような要領のマクロで実現できます。
//ASCII 文字以外の西欧文字に置換するマクロ
//*******検索状態を保持
#reg_search=searchmode;
writeininum "hidemaru.ini","Env","SelectFound",1;
envchanged;
$search=searchbuffer;
#search=searchoption;
##x = x;
##y = y;
disabledraw;
goscreentop;
##sctop = y;
gofileend;
while( 1 ){
searchup "[A-Za-z][0-9]",regular;
if( !result )break;
call getChar gettext(seltopx,seltopy,selendx,selendy);
if(strlen($$return) != 0){//何故か if($$return != "") で判定不可
delete;
delete;
insertfix $$return;
}
}
//******検索を初期状態に戻す
if(!#reg_search){
writeininum "hidemaru.ini","Env","SelectFound",#reg_search;
envchanged;
}
setsearch $search, #search;
enabledraw ##sctop;
moveto ##x,##y;//なるべくマクロ開始時の表示に近づける
endmacro;
getChar://設定した文字との対応
if( $$1 == "c2")return "\xE7";//これは髭付きの小文字 c
//以下 else if で同様の設定、
//\x の後の数字は、秀丸で「文字コード表示」を使えばよい。
//上記の例の場合、Shift-JIS に「0xE7」と表記されるはず
else return "";//設定が無い場合の処理
|
|