| |
haruさん，セイさん，こんばんは。
「秀丸エディタβ版＆鶴亀メール常連さんフォーラム・秀丸エディタβ版」
#01976の続きです。
少し不具合がありましたので修正しました。
//------ ReformX.mac ---------------------------------------//
//画面表示のまま改行を入れて整形
//範囲選択していれば選択範囲内，
//していなければカーソルのある行または全文を対象
#tabspace = 1; // 1:タブスペース変換の問い合わせをする 0:しない
openreg "CURRENTUSER", "Software\\Hidemaruo\\Hidemaru\\Env";
#cb = getregnum( "CRBurasage" );
if( !#cb ) {
question "改行文字をぶら下げにします，いいですか？";
if( result == yes ) {
writeregnum "CRBurasage", 1;
envchanged;
} else {
closereg;
endmacro;
}
}
closereg;
if( !kinsokustate ) config "k+";
if( selecting ) {
#topy = seltopy;
escape;
moveto selendx, selendy;
} else {
menu "&1 カーソル行のみ", "&2 全 文";
if( result ==1 ) {
golinetop2;
#topy = y;
golineend2;
} else {
#topy = 0;
gofileend;
}
}
if( ( code != 0x0d ) && x > 0 ) insertreturn;
#endy = y;
moveto 0, #topy;
disabledraw;
while( y < #endy ) {
if( code == 0x09 ) #tab = 1;
while( !return ) {
golineend;
right;
#x = x; //改行の次のカーソル位置
insertreturn;
while( x < #x ) insert " "; //インデントなどの処理
}
moveto 0, y + 1;
}
if( #tab == 0 || #tabspace == 0 ) endmacro;
question "タブを半角スペースに変換しますか？";
if( result) {
moveto 0, #topy;
beginsel;
moveto 0, #endy;
tospace;
escape;
}
endmacro;
//------------------------------------------------------------//
では， (^^)/~
|
|