| |
アルビレオさん、みなさん、こんにちは。
あまり検証せずにアップしているのがバレバレですね。すみません。
解決しているようなので私の自己満足のような気がしてきましたが。(^^;;
**************************************************
//// 数値から強調定義の意味を表示する Yasuhisa,2004 ////
$youto1[0x01] = "強調１"; // 1 ; 0000 0001
$youto1[0x41] = "強調２"; // 65 ; 0100 0001
$youto1[0x81] = "強調３"; // 129 ; 1000 0001
$youto1[0xC1] = "強調４"; // 193 ; 1100 0001
$youto1[0x05] = "特に強調１"; // 5 ; 0000 0101
$youto1[0x45] = "特に強調２"; // 69 ; 0100 0101
$youto1[0x03] = "行の強調１"; // 3 ; 0000 0011
$youto1[0x43] = "行の強調２"; // 67 ; 0100 0011
$youto2[0x08] = "大文字/小文字を区別しない"; // 8 ; 0000 1000
$youto2[0x10] = "正規表現"; // 16 ; 0001 0000
$youto2[0x20] = "単語"; // 32 ; 0010 0000
// 数値取得 //
selectline;
#HilightCode = val( gettext( seltopx, seltopy, selendx, selendy ) );
// カーソル上の数値
if( #HilightCode == 0 ) {
#HilightCode = val(input( "調べたい強調定義用の番号" ));
// 数値入力
if( #HilightCode == 0 ) endmacro;
}
#code1 = #HilightCode & 0xC7;
#code2[0] = #HilightCode & 0x08;
#code2[1] = #HilightCode & 0x10;
#code2[2] = #HilightCode & 0x20;
$msg = "強調定義用の番号 [ " + str(#HilightCode) + " ]\n----------\n";
// 判定処理 //
if( $youto1[#code1] == "" )
$msg = $msg + "不正な数値です!!";
else{
// 表示方法
$msg1 = $youto1[#code1];
// 検索方法
#num = 0;
while( #num <= 2 ){
if( #code2[#num] != 0 ){
if( $msg2 != "" ) $msg2 = $msg2 + ", ";
$msg2 = $msg2 + $youto2[#code2[#num]];
}
#num = #num + 1;
}
$msg = $msg + "表示方法 : " + $msg1 + "\n検索方法 : " + $msg2;
}
// 表示 //
message $msg;
**************************************************
|
|