| |
六甲のおいしい水さん，こんばんは。
》で、マクロを実行させて、ドラッグ→保存、ドラッグ→保存という具合にでき
》ればいいな、と思っている次第ですが。
次のマクロで試してください。
タイトルバーに指示が表れます。
//-------- DivideSave.mac ----------------------------------------------//
// 選択範囲を連続保存
#confirm = 1; //1:ファイル名を毎回確認する，0:しない
if( !selecting ) {
message "範囲選択して下さい";
endmacro;
}
Begin:
$zero = "0000000";
#handle1 = hidemaruhandle(0);
$inifile = hidemarudir + "\\MyMacro.ini";
$base = getinistr($inifile, "SerialSave", "base");
#number = getininum($inifile, "SerialSave", "number");
#figure = getininum($inifile, "SerialSave", "figure");
if( "base" == "" || #number == 0 ) call NewFile;
MakeName:
$number = rightstr( $zero + str(#number + 1), #figure );
if( #confirm ) {
$name = input("ファイル名（新規の場合はスペース）",
$base + $number + ".txt");
if( !result ) endmacro;
if( $name == " " || $name == " " ) {
call NewFile;
goto MakeName;
}
} else $name = $base + $number + ".txt";
copy;
openfile "/h";
#handle2 = hidemaruhandle(0);
paste;
saveas $name;
#handle2 = hidemaruhandle(0);
setactivehidemaru #handle1;
closehidemaru #handle2;
writeininum $inifile, "SerialSave", "number", val($number);
inputpos "次の範囲を選択してリターンキーを押して下さい。中止は [Esc]";
if( iskeydown( 0x0d ) ) goto Begin;
else {
menu "&E 完 了",
"&C 後で継続";
if( result == 1 ) {
writeinistr $inifile, "SerialSave", "base", "";
writeininum $inifile, "SerialSave", "number", 0;
}
}
endmacro;
NewFile:
$base = input("新規ファイルの基本名を指定して下さい");
if( $base == "" ) endmacro;
#figure = val(input("付加番号の桁数を指定して下さい"));
if( #figure == 0 ) endmacro;
writeinistr $inifile, "SerialSave", "base", $base;
writeininum $inifile, "SerialSave", "number", 0;
writeininum $inifile, "SerialSave", "figure", #figure;
#number = 0;
return;
//----------------------------------------------------------------
では， (^^)/~
山紫水明
|
|