| |
白雲斎と申します。
メニューの「その他」→「動作環境」→「検索」にある「検索での表示」が
「点滅表示」になっていませんか？
ここの設定を「範囲選択」にして問題があるか試して欲しいです。
●問題がなければ、
『設定を「範囲選択」にして、以前のマクロを使用する。』
か、
『設定は「点滅表示」で、末尾のマクロを使用する。』
でどうでしょう。
●問題があれば、
・・・どうすれば良いのか分かりません。
// マクロ ここから -------------------
// 実行後の中断はESCキー
$sb = searchbuffer;
#so = searchoption;
$zn[0] = "〇";
$zn[1] = "一";
$zn[2] = "二";
$zn[3] = "三";
$zn[4] = "四";
$zn[5] = "五";
$zn[6] = "六";
$zn[7] = "七";
$zn[8] = "八";
$zn[9] = "九";
disablebreak; // レジストリを書き換えるので、マクロ中断を禁止する。
disabledraw;
openreg "CURRENTUSER", "Software\\Hidemaruo\\Hidemaru\\Env";
#selectFound = getregnum("SelectFound");
if( !#selectFound )
{
writeregnum "SelectFound", 1;
envchanged;
}
closereg;
gofiletop;
searchdown2 "[0-9０-９]+", regular;
while( result )
{
if( iskeydown(0x1B) )
{
question "マクロを中断しますか？";
if( result ) goto MEND;
}
tohankaku;
#tx = seltopx;
#ty = seltopy;
#ex = selendx;
#ey = selendy;
$buff = gettext(#tx, #ty, #ex, #ey);
escape; // 念のため
if( strlen($buff) == 2 ) call toZen2c $buff;
else call toZen $buff;
beginsel;
moveto #ex, #ey;
insert $$return;
finddown;
}
gofiletop;
MEND:
if( !#selectFound )
{
openreg "CURRENTUSER", "Software\\Hidemaruo\\Hidemaru\\Env";
writeregnum "SelectFound", #selectFound;
envchanged;
closereg;
}
enabledraw;
setsearch $sb, #so;
endmacro;
toZen:
$$n = "";
##l = strlen($$1);
##i = 0;
while( ##i < ##l )
{
$$n = $$n + $zn[val( midstr($$1, ##i, 1) )];
##i = ##i + 1;
}
return $$n;
toZen2c:
if( $$1 == "10" ) return "十";
##ln = val(leftstr($$1, 1));
##rn = val(rightstr($$1, 1));
if( ##ln == 1 ) return "十" + $zn[##rn];
else if( ##ln == 0 ) return $zn[##ln] + $zn[##rn];
else if( ##rn == 0 ) return $zn[##ln] + "十";
return $zn[##ln] + "十" + $zn[##rn];
// マクロ ここまで -------------------
__________________________________________________
GANBARE! NIPPON!
Yahoo! JAPAN JOC OFFICIAL INTERNET PORTAL SITE
http://mail.ganbare-nippon.yahoo.co.jp/
|
|