質問です：秀丸を重ね、並べる - 秀丸エディタマクロ作者会議室 - スレッド05151, 2006/06/02

質問です：秀丸を重ね、並べる

飛梅さん　06/06/02 15:20

　こちらでは一再ならずお世話になっております。さて、８年前にメモを参照しなが
ら作業するためのマクロとして、画面左半分にメモ、右半分に文書作成中のファイル
をそれぞれ最大化して併置する

nexthidemaru; // 次の秀丸
windowhorz; // 秀丸を横に並べる
prevhidemaru; // 前の秀丸
endmacro;

というシンプルなマクロを作っていただき、大変便利に使用しております。
今回のご相談は、アイコンを含む複数のメモファイルを画面左半分にぴったり「重ね
て表示」し、右半分に作業用のファイルを置くマクロをつくれないかというものです。

自作を試み、

nexthidemaru;
setwindowpos 0,0;
prevhidemaru;
setwindowpos 400,0;
endmacro;

が近い出来なのですが、意図とは違ってメモの一部が画面右半分の作業用のファイル
の下に潜り込んでしまいます。ヒントなど頂ければ幸いです。よろしくお願いします。

RE:05151 質問です：秀丸を重ね、並べる

h-tom さん　06/06/04 09:56

h-tom です。

>が近い出来なのですが、意図とは違ってメモの一部が画面右半分の作業用のファイル
>の下に潜り込んでしまいます。ヒントなど頂ければ幸いです。よろしくお願いします。
setwindowpos は座標だけでなく、縦横サイズも指定できるので、重ならないように
指定すればいいのでは？
画面サイズ等は、「ウィンドウ関連キーワード」で取得できます。

//左半分
setwindowpos xworkarea,yworkarea,cxworkarea/2 ,cyworkarea;
//右半分
setwindowpos xworkarea + (cxworkarea/2),yworkarea,cxworkarea/2 ,cyworkarea;

RE:05152 質問です：秀丸を重ね、並べる

飛梅さん　06/06/05 11:21

h-tom様、ご返信ありがとうございます。
　最初の説明が舌足らずでした。「メモの一部が潜り込む」のではなく、「複数起動
したメモファイルのうち、一部のファイルが作業用ファイルの真下に潜り込む」ので
す。
　目下、作業用ファイル以外のファイルをひとつずつ、画面左半分に移すマクロが、
目的の動作に近いと考えております。午後にでも作成を試みます。どうもありがとう
ございました。

RE:05153 質問です：秀丸を重ね、並べる

白雲斎 さん　06/06/05 14:52

こんにちは飛梅さん、白雲斎です。

以下のマクロはどうですか？

// 作業用ファイルの上で実行すること
#lx = xworkarea;
#xSize = cxworkarea / 2;
#rx = #wx + #xSize;
#hd = hidemaruhandle(0);

if( tabmode ) goto TabMode;
if( hidemarucount == 1 ) endmacro;
while( true )
{
nexthidemaruicon;
if( windowstate != 1 ) showwindow 1;
if( hidemaruhandle(0) == #hd )
{
setwindowpos #rx, yworkarea, #xSize, cyworkarea;
break;
}
else setwindowpos #lx, yworkarea, #xSize, cyworkarea;
}
endmacro;

TabMode:
if( tabgrouptotal == 1 ) endmacro;
#i = 0;
while( #i < tabgrouptotal )
{
setactivehidemaru getcurrenttab( true, #i );
if( windowstate != 1 ) showwindow 1;
if( #i == 0 ) setwindowpos #rx, yworkarea, #xSize, cyworkarea;
else setwindowpos #lx, yworkarea, #xSize, cyworkarea;
#i = #i + 1;
}
setactivehidemaru #hd;
endmacro;

RE:05154 白雲斎様　ありがとうございまし

飛梅さん　06/06/05 21:59

白雲斎様
　制作までして頂き、本当にありがとうございます。
先ほど自宅のデスクトップで試したところです。
今度は１０年ぐらい愛用します。重ねてお礼申し上げます。