| |
どもっ、TAKA です。
>（NiftyでTAKAさんが書かれたマクロも掲載できればいいですね）
今、私が使っているマクロ（KEY_ASIN.MAC）と初期値ファイル
（HIDERED.INI）です。
初期値ファイルは、秀丸フォルダ下のREDというフォルダにあると
いう前提になっています。
他のことに忙しくて、ほとんど協力できませんが、とりあえずマク
ロと初期値ファイルの定義例を書いてみます。
ちなみに、レスポンスが気になったことはありません。
//---------------------- マクロここから --------------------
//TAB4
//--------------------------------------------------------------------------//
// マクロ名 : KEY_ASIN.MAC //
// //
// 機能概要 : キー割り当てにマクロ数の制限をなくす //
// //
// 注意事項 : 1. hidered.iniファイルの以下の内容を使用 //
// セクション名[Key_Asin],キー名[押下キー] //
// 書式 押下キー=マクロファイル名 //
// 「押下キー」は、キー割り当てのキーリストに表示されるもの //
// と同一 //
// //
// 使 用 例 : 1. hidered.iniファイルに以下の内容を定義 //
// [Key_Asin] //
// Alt+A=LTOPCHAR.MAC //
// 2. [Alt]+[A]に、このマクロ「KEY_ASIN.MAC」を割り当て //
// 3. [Alt]+[A]押下で、「LTOPCHAR.MAC」が実行 //
// //
// 作 成 者 : 高田 1997年10月25日 //
// //
// 修正履歴 : //
// 修正日 修正者 修正概要 //
// ------------------------------------------------------------------------ //
// XX/XX/XX XXXXXXXX XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX //
//--------------------------------------------------------------------------//
//----------------------//
// 処理開始 //
//----------------------//
//--------------------------------------//
// Alt,Shift,Ctrl押下チェック //
//--------------------------------------//
#Alt = 0;
if( iskeydown( 0x12 ) )
{ //---- Alt ----//
#Alt = 1;
}
#Shift = 0;
if( iskeydown( 0x10 ) )
{ //---- Shift ----//
#Shift = 1;
}
#Ctrl = 0;
if( iskeydown( 0x11 ) )
{ //---- Ctrl ----//
#Ctrl = 1;
}
//----------------------------------//
// 通常キー押下チェック //
//----------------------------------//
#iflg = 0;
//---- ファンクションキー ----//
#i = 0;
while( #i < 12 )
{
if( iskeydown( 0x70 + #i ) )
{
$key = "F" + str( #i + 1 );
#iflg = 1;
goto L1000;
}
#i = #i + 1;
}
#tbl[0] = 0x24; $tbl[0] = "Home";
#tbl[1] = 0x23; $tbl[1] = "End";
#tbl[2] = 0x08; $tbl[2] = "Bksp";
#tbl[3] = 0x0D; $tbl[3] = "Return";
#tbl[4] = 0x2D; $tbl[4] = "Ins";
#tbl[5] = 0x2E; $tbl[5] = "Del";
#tbl[6] = 0x26; $tbl[6] = "Up";
#tbl[7] = 0x28; $tbl[7] = "Down";
#tbl[8] = 0x27; $tbl[8] = "Right";
#tbl[9] = 0x25; $tbl[9] = "Left";
#tbl[10] = 0xC0; $tbl[10] = "@";
#i = 0;
while( #i < 11 )
{
if( iskeydown( #tbl[#i] ) )
{
$key = $tbl[#i];
#iflg = 1;
goto L1000;
}
#i = #i + 1;
}
//---- アルファベットキー ----//
#i = 0;
while( #i < 26 )
{
if( iskeydown( 0x41 + #i ) )
{
$key = char( 0x41 + #i );
#iflg = 1;
goto L1000;
}
#i = #i + 1;
}
#tbl[0] = 0xDB; $tbl[0] = "[";
#tbl[1] = 0xDC; $tbl[1] = "\\";
#tbl[2] = 0xDD; $tbl[2] = "]";
#tbl[3] = 0xDE; $tbl[3] = "^";
#i = 0;
while( #i < 4 )
{
if( iskeydown( #tbl[#i] ) )
{
$key = $tbl[#i];
#iflg = 1;
goto L1000;
}
#i = #i + 1;
}
if( #Shift == 1 )
{
#tbl[0] = 0xE2; $tbl[0] = "_";
#tbl[1] = 0xBC; $tbl[1] = "<";
#tbl[2] = 0xBE; $tbl[2] = ">";
#i = 0;
while( #i < 3 )
{
if( iskeydown( #tbl[#i] ) )
{
$key = $tbl[#i];
#iflg = 1;
#Shift = 0;
goto L1000;
}
#i = #i + 1;
}
}
//----------------------//
// マクロ実行 //
//----------------------//
L1000:
if( #iflg == 1 )
{ //---- キー押下あり ----//
$key_asin = "";
if( #Alt == 1 )
{
$key_asin = $key_asin + "Alt+";
}
if( #Shift == 1 )
{
$key_asin = $key_asin + "Shift+";
}
if( #Ctrl == 1 )
{
$key_asin = $key_asin + "Ctrl+";
}
$key_asin = $key_asin + $key;
$mac = getinistr( hidemarudir + "\\red\\hidered.ini", "Key_Asin", $key_asin );
if( $mac == "" )
{
message "「hidered.ini」の「[Key_Asin]セクション」の「[" + $key_asin + "]キー」に「マクロファイル名」を登録して下さい";
}
else
{
execmacro $mac;
}
}
endmacro;
//---------------------- マクロここまで --------------------
//------------------ 初期値ファイルここから ----------------
[Key_Asin]
Ctrl+@=METAKEY.MAC
Shift+Return=SHELLEXE.MAC
Ctrl+L=SRCHGET.MAC
Ctrl+\=CUT2SRCH.MAC
Shift+Ctrl+L=TB_CLEAR.MAC
Ctrl+^=SRCH2CUT.MAC
Ctrl+[=ERRPASTE.MAC
Ctrl+O=TABDSP.MAC
Shift+Ctrl+S=FNM2SRCH.MAC
Ctrl+U=SRCHCHG.MAC
Ctrl+Y=DEL_LINE.MAC
Ctrl+Ins=INS_DL.MAC
End=WSIZECHG.MAC
Shift+Ctrl+@=METAKEY2.MAC
Ctrl+P=SRCHUP.MAC
Ctrl+N=SRCHDN.MAC
Shift+Ctrl+A=LTOPCHAR.MAC
Shift+Ctrl+I=LE_JUST.MAC
Shift+Ctrl+[=KEY_UNDO.MAC
//------------------ 初期値ファイルここまで ----------------
|
|