| |
toriさん，こんにちは。
》メールアドレスの入力でオートコンプリートはできないものでしょうか？
》かなりOutlook Expressを意識してますが、唯一よかった機能なので鶴亀メール
》でもサポートして欲しいです。
自動的にというわけにはいきませんが，名前なり，アドレスの一部を入力して次
のマクロを実行すると，完全なアドレスが入ります。（うまく作動すればの話です
が）
いずれ，自動的に入るようにサポートされるかもしれませんが，とりあえずはマ
クロでということではいかがでしょう。
では， (^^)/~
山紫水明
//-------- TKMakeupAddress.mac --------------------------------------//
// 鶴亀メールでアドレス入力の補完まくろ Ver1.00 山紫水明
// 名前かアドレスの一部を入力してこのマクロを実行してください。
Turukame: //鶴亀メール上での動作
loaddll "TKinfo.dll";
if( result ){
if( dllfunc( "IsTuruKame" ) ){
golinetop;
beginsel;
golineend;
copy;
runsync "\"" + hidemarudir + "\\hidemaru.exe\" /h/x"
+ currentmacrofilename;
//秀丸から復帰後
beginclipboardread;
$name = getclipboard;
$name = leftstr( $name, strlen( $name ) - 1 );
if( $name == "" ) endmacro;
$address = getclipboard;
menu "&N) 名前を入れる", "&A) アドレスのみ";
#r = result;
if( #r == 0 ) endmacro;
golinetop;
deleteafter;
if( #r == 1 ) insert $name + " <" + $address + ">";
else insert $address;
endmacro;
}
}
//秀丸上での動作
#handle = hidemaruhandle( 0 );
beginclipboardread;
$addresspart = getclipboard;
openreg "CURRENTUSER", "Software\\Hidemaruo\\TuruKame\\Config";
$home = getregstr( "HomeDir" );
closereg;
openfile $home + "\\Adrbook.txt";
gofiletop;
while( 1 ) {
searchdown $addresspart;
if( !result ) break;
else {
#n = #n + 1;
golinetop;
beginsel;
searchdown ",";
$name[#n] = gettext( seltopx, seltopy, selendx, selendy );
escape;//念のため
right;
beginsel;
searchdown ",";
$address[#n] = gettext( seltopx, seltopy, selendx, selendy );
$nameall[#n] = $name[#n] + "\t" + $address[#n];
}
}
if( !#n ) message "アドレス帳にありません";
closehidemaru #handle;
//message str(#n);
#adr = 1;
if(#n > 1) {
$nameall[0] = "選択してください";
menuarray $nameall, #n + 1;
#adr = result - 1;
}
setclipboard $name[#adr] + "\n";
addclipboard $address[#adr];
quit;
//-------------------------------------------------------------------//
|
|