| |
TUBU-REDさん，こんばんは。
》フォルダを名前の昇順にソートする方法を、マクロ等で実現する
》方法をご教授願えないでしょうか？
次のようなマクロで試してみてください。ただし，万一のために，ホームディレ
クトリごとバックアップを取ってから，やってみてください。
危険かもしれませんので，自己責任でお願いします。
//---------- TKSortFolder.mac -------------------------------//
//フォルダを整列し直す
loaddll "tkinfo.dll";
if( !result ) goto Hidemaru;
if( !dllfunc("IsTuruKame") ) goto Hidemaru;
if( dllfunc("IsTrayIcon") ) {
message "常駐を終わらせてください。";
endmacro;
}
#n = dllfunc( "Exit" );
run "\"" + hidemarudir + "\\hidemaru.exe\" /xTKSortFolder.mac";
endmacro;
// 秀丸での動作
Hidemaru:
openreg "CURRENTUSER","Software\\Hidemaruo\\TuruKame\\Config";
$home = getregstr("HomeDir");
closereg;
#handle0 = hidemaruhandle(0);
grep ".\\n", "subdir.bin", $home, regular, subdir, filelist;
replaceallfast "\\(1\\)\\n", "\\n", regular;
#handle_g = hidemaruhandle(0);
gofiletop;
while( code != eof ){
golinetop2;
beginsel;
golineend2;
$sb = gettext( seltopx, seltopy, selendx, selendy );
openfile "\"" + $sb + "\"";
#handle1 = hidemaruhandle(0);
selectall;
run "sort < con > con";
#i = #i + 1;
//確認が必要なければ，以下３行コメント化
question "変更を保存しますか？";
if( result == yes ) save;
else #i = #i - 1;
setactivehidemaru #handle_g;
closehidemaruforced #handle1;
movetolineno 1, lineno + 1;
//以下２行必要であれば，活かす
// question "continue ?";
// if( result == no ) break;
}
message "終わりました。\n" str(#i) + " 個の subdir.bin を処理しました。";
quit;
endmacro;
//----------------------------------------------------------------//
では， (^^)/~
山紫水明
|
|