| |
こんにちは。MAKOPIです。
>送信エディタのアドレス欄から””で囲まれた部分を一発で削除して
>くれるようなマクロは無いでしょうか？？
>教えていただけると助かります。
以下のマクロでどうですか？
//-------- 名前削除.mac ---------------------------------
if( readonly ) //上書き禁止か?
{
message "上書き禁止です。";
endmacro;
}
loaddll "TKInfo.dll";
if( !result )
endmacro;
disabledraw; // 描画禁止
call DeleteNameSpace("To");
call DeleteNameSpace("Cc");
endmacro;
DeleteNameSpace:
##HeaderMax = dllfunc("CountCurrentHeader",$$1);
##HeaderCount = 0;
while(##HeaderCount < ##HeaderMax)
{
//// ヘッダ分繰り返し
$$AddrssList = dllfuncstr("CurrentHeader2",$$1,##HeaderCount);
##ListMax = dllfunc("CountEmailList", $$AddrssList);
##ListCount = 0;
$$AllEmailAdd = "";
$$Delimiter = "";
while(##ListCount < ##ListMax)
{
//// アドレス数分繰り返し
$$Address = dllfuncstr("GetEmailList", $$AddrssList, ##ListCount);
$$EmailAdd = dllfuncstr("SetEmailOnly",$$Address);
$$AllEmailAdd = $$AllEmailAdd + $$Delimiter + $$EmailAdd;
$$Delimiter = ", ";
##ListCount = ##ListCount + 1;
}
if($$AllEmailAdd != "")
{
$$s = dllfuncstr("SetHeader2",$$1,$$AllEmailAdd,##HeaderCount);
}
##HeaderCount = ##HeaderCount + 1;
}
return;
//-------- ここまで ---------------------------------
|
|