カレンダ - 秀丸メール情報交換会議室 - スレッド12523, 2003/04/24

marbas さん　03/04/24 10:25

はじめまして、鶴亀メールを使わせていただいている者です。

鶴亀メールのフォルダウィンドウの下にカレンダを
表示させる方法などはあるのでしょうか？

スケジュール機能とかはいらないのですが、
今月のカレンダがあると便利だなと思いまして・・・
すでになんらかの方法があったら教えてください。

以上、宜しくお願いします。

RE:12523 カレンダ

たけのこ さん　03/04/24 10:42

たけのこです。

タスクバーに時刻を表示させる設定にしておいて、その時刻をダブルクリックす
ると表示されます。または、下記のようなマクロを登録して、何かキーを割り当
てておくとか。

/////
run "control.exe timedate.cpl";
/////

他にも壁紙に前月・当月・翌月のカレンダーを表示させるアプリなんかがありま
すね。カレンダーを見るのは、メール一覧と言うよりは、メールエディタの方が
いいと思いますが……。

すいません、*横*向きの回答で。

(^^)/”

RE:12523 カレンダ

Mattz さん　03/04/24 10:43

>鶴亀メールのフォルダウィンドウの下にカレンダを
>表示させる方法などはあるのでしょうか？

そのお仕事を鶴亀にやらせなければならない理由が思いつかないんですが。
既存のデスクトップカレンダーソフトなど利用すれば済む話かと。

RE:12525 カレンダ

marbas さん　03/04/24 11:17

たけのこさん、Mattzさん、回答をありがとうございます。

基本的にワンアクション無しでカレンダが見たいだけなんです。

タスクから時計をダブルクリックする場合
カレンダウィンドウが出てしまい、鶴亀メールが隠れて
しまいます。

あと、壁紙にカレンダなんですが
ノートなもので画面サイズが1024×768なんです
大体、全画面に開発用のウィンドウを広げて作業している為
壁紙が見えません。
常に前面に表示という手もあるのでしょうが、それでは使い勝手が
悪い、という事で・・・

あんま、面倒臭がってはいけないのかな！？
ありがとうございました。

RE:12523 カレンダ

s_yam さん　03/04/24 11:36

>鶴亀メールのフォルダウィンドウの下にカレンダを
>表示させる方法などはあるのでしょうか？

アプリケーションの開発をされているようでしたら、カレンダーを
表示するアプリケーションを作成して、鶴亀メール起動時のマクロで
起動すればよいと思います。
鶴亀メール本体ウィンドウのハンドルを渡せば、追尾させたりする
ことも可能だと思います。

RE:12523 カレンダ

秀まるお2 さん　03/04/24 14:50

　既にいろいろコメントされてますが、一応作者からもコメントさせていただき
ますと、鶴亀メールの本体ウィンドウの中にカレンダーのような物を表示する機
能は現状で存在せず、将来的にも追加する予定も無いです。

　カレンダーというか、スケジュール管理ソフトのような物を中に組み込んで欲
しいという要望は過去にありましたが、技術的な難易度を考えると難しいです。

　たけのこさんの紹介された方法は僕も知りませんでしたが、それが一番手っ取
り早いんじゃないかと思います。

RE:12529 カレンダ

Salem さん　03/04/24 15:13

きっと、marbasさんの要望を拡大解釈して、その機能を拡大していくと、下記の記事
のような、今後のメールという機能を主眼として、派生するビジネスツール(EIPやグ
ループウェアやKM)への発展性を示唆した内容になるでしょうね。

http://japan.internet.com/busnews/20030303/5.html

個人的にこの方向性も有りだと思いますが、鶴亀には期待したくないですね。

RE:12523 カレンダ

たまがわ さん　03/04/24 22:34

　フォルダペインにカレンダーを表示するマクロです（って、ジョークマクロに近い
ですけど、案外カレンダー欲しい人には役に立つかも・・・）
　等幅フォントじゃないときれいに見えないです。

// フォルダペインにカレンダー
// calendar.mac
loaddll "tkinfo.dll";
#n = dllfunc("MakeAccount", "◆ " + year + "年 " + month + "月");
// #n = dllfunc("SelectFolder", dllfuncstr("CurrentAccount"), "");
#n = dllfunc("MakeFolder", " 日月火水木金土");
#year = val(year);
#month = val(month);
call TheFirst;
#i = 0; $week = "";
while (#i < #first) {
$week = $week + " ";
#i = #i + 1;
}
call HowManyDays;
#i = 1;
while (#i <= #days) {
$week = $week + rightstr(" " + str(#i), 3);
#first = #first + 1;
if (!(#first % 7)) {
#n = dllfunc("MakeFolder", $week);
$week = "";
}
#i = #i + 1;
}
#n = dllfunc("MakeFolder", $week);
endmacro;

TheFirst:
if (#month < 3) #year = #year - 1;
#first = (#year + (#year / 4) - (#year / 100) + (#year / 400)
+ val(midstr("032503514624", #month - 1, 1)) + 1) % 7;
return;

HowManyDays:
#days = val(midstr("312831303130313130313031", (#month - 1) * 2, 2));
if ((#month == 2) &&
((#year % 4 == 0) && ((#year % 100 != 0) || (#year % 400 == 0)))) {
#days = #days + 1;
}
return;

RE:12533 カレンダ

NOP さん　03/04/25 10:47

たまがわさん、こんにちは。NOP といいます。

>　フォルダペインにカレンダーを表示するマクロです（って、ジョークマクロに近い

これ、とっても良いです。（ジョークにはもったいないです）
使用させていただきます。

# ただ毎月、アカウント増えちゃうのかな？

RE:12547 カレンダ

たまがわ さん　03/04/25 11:40

　NOPさん、こんにちは。

> これ、とっても良いです。（ジョークにはもったいないです）
> 使用させていただきます。

　おおっ、なんだかうれしいです。
　でもこれ、５月になるとエラーになることが分かりました。（最終日が土曜日だと
エラー）
　endmacroの上の行を
if ($week != "") #n = dllfunc("MakeFolder", $week);
と直していただければ、大丈夫です。

> # ただ毎月、アカウント増えちゃうのかな？

　手動でアカウントを削除していただくということですよね。月替わりに更新するよ
うに修正できなくはないですけど。

RE:12551 カレンダ

NOP さん　03/04/25 13:13

>　おおっ、なんだかうれしいです。
>　でもこれ、５月になるとエラーになることが分かりました。

私にとってはとても有用なマクロです。

現在は若干マクロに手を入れさせていただいて、カレントアカウントに
カレンダフォルダを作成するようにして使用しています。

ありがとうございました。

RE:12551 カレンダ

たまがわ さん　03/04/25 13:19

> > # ただ毎月、アカウント増えちゃうのかな？
> 　手動でアカウントを削除していただくということですよね。月替わりに更新するよ
> うに修正できなくはないですけど。

　月が変わってから実行すると、前のカレンダーを削除して、新しいカレンダーを作
ります。（先のマクロでカレンダーを作った場合は、このマクロも一度実行しておい
てください）

// フォルダペインにカレンダー
// calendar.mac
loaddll "tkinfo.dll";
$ini = dllfuncstr("HomeDir") + "calendar.ini";
$ThisMonth = "◆ " + year + "年 " + month + "月";
if (existfile($ini)) {
$RcdMonth = getinistr($ini, "calendar", "1");
if (dllfunc("SelectFolder", $RcdMonth, "")) {
if ($ThisMonth == $RcdMonth) endmacro;
#n = dllfunc("SetAutoPushTimer", 0, "yes");
#n = sendmessage(hidemaruhandle(0), 0x0111, 40025, 0);
}
} else {
if (dllfunc("SelectFolder", $ThisMonth, "")) {
writeinistr $ini, "calendar", "1", $ThisMonth;
endmacro;
}
}
#n = dllfunc("MakeAccount", $ThisMonth);
#n = dllfunc("MakeFolder", " 日月火水木金土");
#year = val(year);
#month = val(month);
if (#month < 3) #year = #year - 1;
#first = (#year + (#year / 4) - (#year / 100) + (#year / 400)
+ val(midstr("032503514624", #month - 1, 1)) + 1) % 7;
#i = 0; $week = "";
while (#i < #first) {
$week = $week + " ";
#i = #i + 1;
}
#days = val(midstr("312831303130313130313031", (#month - 1) * 2, 2));
if ((#month == 2) &&
((#year % 4 == 0) && ((#year % 100 != 0) || (#year % 400 == 0)))) {
#days = #days + 1;
}
#i = 1;
while (#i <= #days) {
$week = $week + rightstr(" " + str(#i), 3);
#first = #first + 1;
if (!(#first % 7)) {
#n = dllfunc("MakeFolder", $week);
$week = "";
}
#i = #i + 1;
}
if ($week != "") #n = dllfunc("MakeFolder", $week);
writeinistr $ini, "calendar", "1", $ThisMonth;
endmacro;