| |
アルビレオです。
>>・すべてのメールはAに集められるので、このメールに対してBから返信する
>> 場合はいったんBに対象のメールをコピーする必要がある。
>
> この部分ですが、Aで返信メールを作成中に、From欄でAlt＋↓でアカウント変
>更という手も使えますね。
> 「返信が多くないなら」ということで。。。。
エディタ上からもアカウントの切り替えができることを忘れていました。(^^;
多用するならSetEditorAccount2を使ってワンタッチで切り替えできるマクロを
用意するのもいいですね。
（あんな長いマクロを書く必要なかったよ…）
せっかくなのでもう一つの問題点、「アカウントAで受信するまでは送信済み
メールが集約されない」という問題も解消するマクロを書いてみました。
これを使えばBccでコピーを送る必要はありません。
エディタ上でAlt+↓で手動切り替えも不要です。
「いますぐ送信」のかわりにこのマクロを使って送信すると何かと便利です。
・新規メールはアカウントBで送信後、メールをアカウントAに移動して送信時の
振り分けを実行する。
・返信/転送メールはアカウントBで送信後、元メールのあるフォルダに送信済み
メールを移動する。
※返信/転送でも振り分けを使うこともできますが、このマクロだと送信完了後
元メールのあるフォルダに移動してくれるのでこちらの方が便利だと思います。
※「あとで送信」ではうまくいきません。
--------
loaddll "TKInfo.dll";
$RecevieAccount = "Aのアカウント名";//←***ここを変更してください***
$SendAccount = "Bのアカウント名";//←***ここを変更してください***
#result = dllfunc("IsTuruKameMain");
if(#result == 1){
message "エディタウィンドウで実行してください";
endmacro;
}
$RootFolder = dllfuncstr("RootFolder");//返信元のフォルダを取得
#result = dllfunc("SetEditorAccount2", $SendAccount, 0);
if(#result == 0){
message "アカウントの切り替えに失敗しました";
endmacro;
}
#result = dllfunc("SendNow");
if(#result == 0){
message "送信に失敗しました";
endmacro;
}
#result = dllfunc("Sync");
if(#result == 0){
endmacro;
}
#handle = hidemaruhandle(0);
#result = dllfunc("SetMainWndTop");
if(#result == 0){
message "本体ウィンドウがありません";
endmacro;
}
closehidemaru #handle;
if($RootFolder==""){//新規メールの場合
#result = dllfunc("Move", $RecevieAccount, "送信済み");
if(#result == 0){
message "メールの移動に失敗しました";
endmacro;
}
#result = dllfunc("SelectFolder", $RecevieAccount, "送信済み");
if(#result == 0){
message "フォルダの選択に失敗しました";
endmacro;
}
#result = dllfunc("DoFilter", 2, 0, 1);//送信済みメールを振り分け
}else{//返信/転送メールの場合
#result = dllfunc("Move", $RecevieAccount, $RootFolder);
if(#result == 0){
message "メールの移動に失敗しました";
endmacro;
}
#result = dllfunc("SelectFolder", $RecevieAccount, $RootFolder);
if(#result == 0){
message "フォルダの選択に失敗しました";
endmacro;
}
}
--------
|
|