| |
まず、メニューから色を選んで切り替えるマクロを１つ作ってみました。
--------------色切り替えマクロ------------------------------
$color[0] = "05000001"; //システム背景色
$color[1] = "FFD0D000"; //薄赤
$color[2] = "D0FFD000"; //薄緑
$color[3] = "FFD0FF00"; //薄紫
$color[4] = "D0D0FF00"; //薄青
$color[5] = "D0FFFF00"; //薄水色
$color[6] = "FFFFD000"; //薄黄色
menu "背景色の指定:", "標準", "薄赤", "薄緑", "薄紫", "薄青", "薄水色",
"薄黄色";
if( result <= 1 ) {
endmacro;
}
$color = $color[result-2];
openreg "CURRENTUSER", "Software\\Hidemaruo\\TuruKame\\Config";
writeregbinary "Color", $color, 4, 1;
loaddll "tkinfo.dll";
#n = dllfunc("EnvChanged");
--------------色切り替えマクロおわり------------------------
でもって、アカウント切り替え時に色変更するマクロですが、例えば僕の所だと、
"斉藤秀夫メイン"
"hideo@maruo.co.jp"
ってアカウントと他にいろいろアカウントがあるんですが、"斉藤秀夫メイン"の時
は薄赤、"hideo@maruo.co.jp"の時は薄緑にするとしたら、以下のようなマクロにな
ります。
--------------色切り替えマクロ------------------------------
$color[0] = "05000001"; //システム背景色
$color[1] = "FFD0D000"; //薄赤
$color[2] = "D0FFD000"; //薄緑
$color[3] = "FFD0FF00"; //薄紫
$color[4] = "D0D0FF00"; //薄青
$color[5] = "D0FFFF00"; //薄水色
$color[6] = "FFFFD000"; //薄黄色
loaddll "tkinfo.dll";
#n = dllfunc("SetJapaneseCodePageMode", 1);
$account = dllfuncstr("CurrentAccount");
if( $account == "斉藤秀夫メイン" ) {
$color = $color[1]; //薄赤
} else if( $account == "hideo@maruo.co.jp" ) {
$color = $color[2]; //薄緑
} else {
$color = $color[0]; //標準
}
openreg "CURRENTUSER", "Software\\Hidemaruo\\TuruKame\\Config";
writeregbinary "Color", $color, 4, 1;
#n = dllfunc("EnvChanged");
--------------色切り替えマクロおわり------------------------
こんなマクロを「マクロ登録 - 自動起動」ページの「アカウント切り替え時」に
登録しておけばいいです。
マクロの中の値は色の値なのですが、基本的にRGBの値を16進数で表してまして、"
D0"の所を例えば"E0"にするともっと薄い色になります。"C0"くらいにするともっと
濃くなります。
|
|