| |
HTMLメールのインライン表示がOFFになってしまう理由ですが、HTMLメールViewer
の存在によってマクロが誤動作することを防ぐ用に、マクロ側で特別な配慮をしてな
い限り、マクロ実行のタイミングでHTMLメールViewerが勝手にOFFになることが多いで。
（具体的には、マクロの中でメール表示の切り替えが発生するとOFFになる）
解決策は、マクロを直すしか無いです。で、今ちょっと僕の方で手直ししてみまし
た。
以下のマクロだと大丈夫なはずということで、お願いします。「SetHtmlMailAutoI
nlineView」って関数呼び出しをしています。
---------------------- All_Unread.mac 手直し版 ----------------------
// アカウントを順番に切り替えすべて既読にする Ver 1.01 by TAMA
// --詳しくは添付のテキストファイルをお読み下さい--
loaddll "tkinfo.dll";
$account = dllfuncstr("CurrentAccount"); // 現在のアカウント名を取得
if ($account == "") { endmacro; } // アカウント名を返さなかった場合は終了
#n = 0;
while (1) {
// n 番目のアカウントのアカウント名を取得
$l[#n] = dllfuncstr("Account", #n);
// 返り値が現在のアカウントだった場合、それが何番目かを記憶
if ($l[#n] == $account) { #current = #n; }
// 返り値が無しの場合、最後のアカウントが何番目かを計算し、ループから抜ける
else if ($l[#n] == "") { #last = #n - 1; break; }
// カウントアップ
#n = #n + 1;
}
if (iskeydown(0x10)) {// Shift キーを押している場合、巡回してすべて既読。
#z = 0;
while((#last + 1) - #z){
//メッセージは非表示
#n = dllfunc("SetAutoPushTimer", 0, "yes");
#n = dllfunc("SelectFolder", dllfuncstr("Account",#z), "");
#n = dllfunc("ClearAllUnread");
#z = #z + 1;
}
#n = dllfunc("SetHtmlMailAutoInlineView", 1); // by 秀まるお
#n = dllfunc("SelectFolder", dllfuncstr("Account",#current), "受信");
} else { // Shift キーを押していない場合、カレントアカウントのみすべて既読
//メッセージは非表示
#n = dllfunc("SetAutoPushTimer", 0, "yes");
#n = dllfunc("SelectFolder", dllfuncstr("Account",#current), "");
#n = dllfunc("ClearAllUnread");
#n = dllfunc("SetHtmlMailAutoInlineView", 1); // by 秀まるお
#n = dllfunc("SelectFolder", $account[#current], "受信");
}
endmacro;
|
|