| |
cumaさん，こんばんは。
》 ・単なるメモとメールで受けた情報から作成するメモが混在出来て
》 一元管理可能。
》 ・一例として顧客から来週の仕事の情報をメールで受信したとします。
》 （１）これを受信した時に、「鶴亀メモへ追加」コマンド実行
》 （２）送受信を目的としないメモフォルダに未分類カテゴリで
》 先ほどのメール本文が入る。出来ればサブジェクトは受信
》 したサブジェクトがデフォルト設定されている。
前のものを少し変えてみました。どこまでご希望に近づけたかわかりませんが。
//------ TKSaveMemo.mac -----------------------------------------------//
// メモ保存マクロ Ver1.03
//「メモ」用フォルダをあらかじめ作成。
//「草稿」フォルダの下に作業用に「sub」フォルダを作っておく。
//アカウントごとに作るなら，それぞれに「メモ」と「sub」を作成する。
//新規メールでメモを作成してエディタ上，または受信メール上でマクロ実行。
//＠印の箇所は適宜カスタマイズ
loaddll "tkinfo.dll";
/////////////////////////////////////////////////////////////
//$MemoFolder = "受信\\メモ"; //メモ用フォルダの指定（「受信」直下の場合）＠
$MemoFolder = "User\\メモ"; //同（アカウント直下の場合）＠
$date = dllfuncstr("CurrentDate", "YYYY年M月D日(W) hh:mm");//＠
$To = "鶴亀メモ：" + $date; //適当に設定＠
$From = dllfuncstr( "CurrentHeader", "From" );
$Subject = dllfuncstr( "CurrentHeader", "Subject" );
#distribute = 0; // 1：振り分けをする 0：しない＠
#account = 0; //「メモ」フォルダのあるアカウント番号＠
//アカウントごとにメモフォルダを作る時は「-1」＠
/////////////////////////////////////////////////////////////
#main = dllfunc( "MainWnd" );
if( dllfunc( "IsTuruKameMain") ) {
#n = dllfunc( "OpenMail" );
} else {
$account = dllfuncstr( "ExecAt", #main, "Account", #account );
}
if( $account != "" ) {
if( dllfuncstr( "CurrentAccount" ) != $account ) {
message "アカウントが違います。\n「From:」 で切り替えてください。";
endmacro;
}
}
#handle = hidemaruhandle(0);
#n = dllfunc( "ExecAt", #main, "SelectFolder", $account, "草稿\\sub" );
//以下３行，上記設定値にヘッダを変更，不要なものはコメントアウト
$s = dllfuncstr( "SetHeader", "To", $To );//＠
$s = dllfuncstr( "SetHeader", "From", $From );//＠
//$s = dllfuncstr( "SetHeader", "X-Date", $date );//＠
#n = dllfunc( "SaveDraft2","sub" );
#n = dllfunc( "SetMainWndTop" );
closehidemaruforced #handle;
#n = dllfunc("SetMailIndex", dllfunc( "MailCountAll") - 1 );
//最新のメールを選択
#n = dllfunc( "Move", $account, $MemoFolder );
#n = dllfunc( "SelectFolder", $account, $MemoFolder );
#n = dllfunc( "SelectPane", 1 );
#IsThreadView = dllfunc("IsThreadView");
if( #IsThreadView ) #n = dllfunc("SetThreadView", 0);
#n = dllfunc("SetMailIndex", dllfunc( "MailCountAll") - 1 );
#n = dllfunc("SetMailFlag", "send", 0);
//改変できるように，受信メールにする
if( #IsThreadView ) #n = dllfunc( "SetThreadView", 1 );
if( #distribute ) { //振り分け実行
#n = dllfunc( "DoFilter", 0, 0, 0 );
#n = dllfunc( "SelectRecvMail" );
}
endmacro;
//振り分け設定で振り分け対象を「受信したメール」または「両方」に設定。
//いったん保存したメモを修正する場合は「設定」→「エディタ」→「受信系」
//→詳細で「受信したメールでも編集可能な状態で開く」に。
//--------------------------------------------------------------------//
では， (^^)/~
山紫水明
|
|