|
宛先の名前部分に「様」を付ける機能はありませんが、マクロで一応実現出来
ます。マクロの内容としては、以下のようになります。
------------------------------------------------------------------
loaddll "tkinfo.dll";
#to_count = dllfunc("CountCurrentHeader", "To");
#cc_count = dllfunc("CountCurrentHeader", "Cc");
#i = 0;
while( #i < #to_count ) {
call SamaChange dllfuncstr("CurrentHeader2", "To", #i);
#n = dllfunc("SetHeader2", "To", $$return, #i );
#i = #i + 1;
}
#i = 0;
while( #i < #cc_count ) {
call SamaChange dllfuncstr("CurrentHeader2", "Cc", #i);
#n = dllfunc("SetHeader2", "Cc", $$return, #i );
#i = #i + 1;
}
endmacro;
SamaChange:
##c = dllfunc("CountEmailList", $$1);
##i = 0;
$$result = "";
while( ##i < ##c ) {
$$one = dllfuncstr("GetEmailList", $$1, ##i);
$$name = dllfuncstr("SetNameOnly", $$one);
$$email = dllfuncstr("SetEmailOnly", $$one);
if( $$email != "" ) {
if( $$name != "" ) {
if( rightstr($$name, 2) != "様" ) {
$$name = $$name + "様";
}
$$one = $$name + " <" + $$email + ">";
} else {
$$one = $$email;
}
if( $$result != "" ) {
$$result = $$result + ", ";
}
$$result = $$result + $$one;
}
##i = ##i + 1;
}
return $$result;
------------------------------------------------------------------
このようなマクロを、例えば「Sama.mac」という風に作成しておいて、それを
「マクロ・マクロ登録・エディタ側」の方に登録しておいて、「様」を付けたく
なったら、その登録したマクロを実行すればいいです。
または、「マクロ・マクロ登録・自動起動」の「後で送信/今すぐ送信時」に
登録しておけば、送信する前にマクロが自動実行されます。
|
|