| |
Mitsさん、こんにちは
>という処理を代替策として取ろうと思ったのですが、
>2の時点でどうしていいものか迷っています。(複数選択が出来ず)
秀まるおさんが、隠しコマンドをサポートフォーラムのどこかで
教えてくださっていました。それを使用すれば複数選択が可能のようです。
下記マクロを参考にしてください。
//Sample Macro
$$ver = "1.00";
$$date = "2002.11.27";
$$author = "プックン" ;
$$fname = currentmacrobasename ;
$$info = "\n" + $$fname + " Ver " + $$ver+ "\n最終更新日付:"+$$date ;
$$info = $$info + "\n作者:"+$$author ;
//Folder設定
$$Folder = "ゴミ箱" ;
call Turukame $$info;
//sample
//鶴亀から起動されたかどうか確認
##n = dllfunc( "IsTuruKame" );
//移動できたかどうかの確認(値のチェック)
call Res_check ##n,"マクロの実行が、鶴亀からされていません。\n" + $$info ;
//アカウント情報の取得
$$account =dllfuncstr("CurrentAccount");
//アカウント情報の確認(文字列の確認)
call Str_check $$account,"アカウント情報の取得に失敗しました。\n" + $$in
fo ;
//Folder情報取得
$$CurrentFolder = dllfuncstr( "CurrentFolder" );
//本体ウィンドウに移動
##n = dllfunc( "SetMainWndTop" );
call Res_check ##n,"鶴亀本体ウィンドウに移動失敗\n" + $$info ;
##n = dllfunc( "SelectFolder", $$Account, $$Folder );
call Res_check ##n,$$Folder + ":フォルダ選択失敗\n" + $$info ;
// 裏技メモ
// フォルダ内のメールをすべて選択(情報元:秀まるおさん)
//Titleの一時変更
title $$Folder + "内のメール削除処理";
// 0x0111 --- WM_COMMAND
// 40008 --- 「すべて選択」のコマンドコード
##n = dllfunc("SelectPane", 1);
##n = sendmessage( findwindowclass("TuruKameFrame")
, 0x0111, 40008, 0 );
// 裏技メモ終了
//$$Folder内のメール削除
##n = dllfunc( "Delete" );
//終了処理無しの、Result Check 第3引数"1"=Skip Optionを指定
call Res_check ##n,"メール削除失敗\n" + $$info ,1 ;
//Title :現在の秀丸のキャプションを元に戻す
title 0 ;
//
##n = dllfunc( "SelectFolder", $$Account, $$CurrentFolder );
call Res_check ##n,$$CurrentFolder + ":フォルダ選択失敗\n" + $$info ;
LEND:
freedll;
endmacro;
Turukame: //鶴亀メール起動チェック&DLLロード
$$info = $$1;
//鶴亀インストールフォルダを取得する。
//戻り値 最後に"\"付きのフォルダ情報
call Get_ins $$info;
$$TuruKameDir = $$return ;
//アカウント情報の確認(文字列の確認)
call Str_check $$TuruKameDir,"鶴亀インストールディレクトリ情報の取得に失
敗しました。\n" + $$info ;
// DLL を Load する
loaddll $$TuruKameDir + "tkinfo.dll";
if( !result ) {
message "DLLロードに失敗\n"+$$info;
endmacro;
}
return ;
//鶴亀インストールディレクトリの取得
//戻り値 最後に"\"付きのフォルダ情報
Get_ins:
$$info = $$1;
openreg "CURRENTUSER","Software\\Hidemaruo\\TuruKame\\Config";
if( !result ) {
message "鶴亀がインストールされてないです (^^;)\n"+$$info;
closereg ;
goto LEND;
}
$$TuruKameDir = getregstr( "TuruKameDir" );
closereg ;
return $$TuruKameDir;
Res_check:
//処理:処理の判定&メッセージ表示
//引数渡し
##num = ##1; $$mes = $$2 ; ##skip = ##3 ;
if(##num != 1){
message $$mes ;
if(!##skip){
goto LEND;
}
}
return ;
Str_check:
//処理:文字列の判定&メッセージ表示
//引数渡し
$$str = $$1; $$mes = $$2 ;
if($$str == ""){
message $$mes ;
goto LEND;
}
return ;
|
|